Conto VLOOKUP Lanjut: Panelusuran Multi-Kriteria

Ing bagean liya saka tutorial kita ing fungsi VPR (VLOOKUP) ing Excel, kita bakal nganalisa sawetara conto sing bakal mbantu sampeyan ngarahake kabeh kekuwatan VPR kanggo ngatasi tugas Excel sing paling ambisi. Conto nganggep sampeyan wis duwe kawruh dhasar babagan cara kerjane fitur iki. Yen ora, sampeyan bisa uga kasengsem miwiti karo bagean pisanan saka tutorial iki, sing nerangake sintaksis lan panggunaan dhasar. VPR. Inggih, ayo miwiti.

• Telusuri ing Excel kanthi macem-macem kritéria
• Kita extract nilai 2nd, 3rd, etc. nggunakake VLOOKUP
• Nompo kabeh repetitions saka nilai sing dikarepake
• Panelusuran XNUMXD kanthi baris lan kolom sing dikenal
• Nggunakake sawetara VLOOKUP ing siji rumus
• Substitusi dinamis data saka tabel beda

Telusuri ing Excel kanthi macem-macem kritéria

fungsi VPR ing Excel minangka alat sing kuat banget kanggo nggoleki nilai tartamtu ing basis data. Nanging, ana watesan sing signifikan - sintaks ngidini sampeyan nggoleki mung siji nilai. Apa yen sampeyan pengin nggoleki kanthi pirang-pirang kondisi? Sampeyan bakal nemokake solusi ing ngisor iki.

Conto 1: Telusuri kanthi 2 kritéria sing beda

Upaminipun kita duwe dhaptar pesenan lan kita pengin golek Jumlahe barang (Qty.), adhedhasar rong kritéria - Jeneng klien (Pelanggan) lan Название продукта (Produk). Prakara iki rumit amarga saben wong sing tuku pesen sawetara jinis barang, bisa dideleng saka tabel ing ngisor iki:

fungsi reguler VPR ora bakal bisa ing skenario iki amarga bakal ngasilake nilai pisanan ketemu sing cocog karo Nilai goleki diwenehi. Contone, yen sampeyan pengin ngerti jumlah barang manisan'dhawuh dening panuku Bukit Jeremy, tulis rumus ing ngisor iki:

=VLOOKUP(B1,$A$5:$C$14,3,FALSE)

=ВПР(B1;$A$5:$C$14;3;ЛОЖЬ)

– rumus iki bakal ngasilake asil 15cocog karo prodhuk Apples, amarga iku nilai pisanan sing cocog.

Ana workaround prasaja - nggawe kolom tambahan kanggo gabungke kabeh kritéria sing dikarepake. Ing conto kita, iki kolom Jeneng klien (Pelanggan) lan Название продукта (Produk). Aja lali yen kolom gabungan kudu dadi kolom paling kiwa ing kisaran telusuran, amarga kolom kiwa fungsine VPR katon munggah nalika nggoleki nilai.

Dadi, sampeyan nambah kolom tambahan menyang tabel lan nyalin rumus ing ngisor iki ing kabeh sel: =B2&C2. Yen sampeyan pengin senar luwih bisa diwaca, sampeyan bisa misahake nilai gabungan kanthi spasi: =B2&» «&C2. Sawise iku, sampeyan bisa nggunakake rumus ing ngisor iki:

=VLOOKUP("Jeremy Hill Sweets",$A$7:$D$18,4,FALSE)

=ВПР("Jeremy Hill Sweets";$A$7:$D$18;4;ЛОЖЬ)

or

=VLOOKUP(B1,$A$7:$D$18,4,FALSE)

=ВПР(B1;$A$7:$D$18;4;ЛОЖЬ)

Ing endi sel B1 ngandhut nilai concatenated saka argumen goleki_nilai (lookup_value) lan 4 – Argumentasi col_index_num (column_number), yaiku nomer kolom sing ngemot data sing bakal dijupuk.

Conto 2: VLOOKUP kanthi rong kritéria kanthi tabel dideleng ing sheet liyane

Yen sampeyan kudu nganyari tabel utama (Tabel utama) kanthi nambahake data saka tabel kapindho (Tabel Lookup), sing ana ing sheet liyane utawa ing buku kerja Excel liyane, sampeyan bisa ngumpulake nilai sing dikarepake langsung ing rumus sing sampeyan lebokake. menyang meja utama.

Kaya ing conto sadurunge, sampeyan butuh kolom tambahan ing tabel Lookup kanthi nilai gabungan. Kolom iki kudu dadi kolom paling kiwa ing kisaran telusuran.

Dadi rumus karo VPR bisa kaya iki:

=VLOOKUP(B2&" "&C2,Orders!$A&$2:$D$2,4,FALSE)

=ВПР(B2&" "&C2;Orders!$A&$2:$D$2;4;ЛОЖЬ)

Ing kene, kolom B lan C ngemot jeneng pelanggan lan jeneng produk, lan link Pesenan!$A&$2:$D$2 nemtokake tabel kanggo katon ing sheet liyane.

Kanggo nggawe rumus luwih bisa diwaca, sampeyan bisa menehi jeneng sawetara tampilan, banjur rumus bakal katon luwih prasaja:

=VLOOKUP(B2&" "&C2,Orders,4,FALSE)

=ВПР(B2&" "&C2;Orders;4;ЛОЖЬ)

Supaya rumus bisa digunakake, nilai ing kolom paling kiwa ing tabel sing sampeyan deleng kudu digabungake kanthi cara sing padha kaya ing kritéria telusuran. Ing gambar ing ndhuwur, kita gabungke nilai u2bu2band sijine spasi ing antarane, kanthi cara sing padha sampeyan kudu nindakake ing argumen pisanan fungsi kasebut (BXNUMX& "" & CXNUMX).

Elingi! fungsi VPR diwatesi kanggo 255 karakter, iku ora bisa nelusuri Nilai sing dawane luwih saka 255 karakter. Tetep ana ing pikiran iki lan priksa manawa dawane nilai sing dikarepake ora ngluwihi watesan iki.

Aku setuju yen nambah kolom tambahan ora solusi sing paling elegan lan ora tansah ditrima. Sampeyan bisa nindakake padha tanpa kolom helper, nanging mbutuhake rumus sing luwih rumit kanthi kombinasi fungsi INDEKS (INDEX) lan MATCH (LUWIH DIBUKA).

Kita extract nilai 2nd, 3rd, etc. nggunakake VLOOKUP

Sampeyan wis ngerti manawa VPR bisa ngasilake mung siji nilai sing cocog, luwih tepat, sing pisanan ditemokake. Nanging apa yen nilai iki diulang kaping pirang-pirang ing array sing dideleng, lan sampeyan pengin ngekstrak nomer 2 utawa 3? Apa yen kabeh nilai? Masalah katon rumit, nanging solusi ana!

Upamane siji kolom tabel ngemot jeneng pelanggan (Jeneng Pelanggan), lan kolom liyane ngemot produk (Produk) sing dituku. Coba goleki barang kaping 2, 3 lan 4 sing dituku dening pelanggan sing diwenehake.

Cara paling gampang yaiku nambah kolom tambahan sadurunge kolom jeneng pelanggan lan isi karo jeneng pelanggan kanthi nomer pengulangan saben jeneng, contone, John Doe 1, John Doe 2 etc.. Kita bakal nindakake trick karo nomer nggunakake fungsi COUNTIF (COUNTIF), amarga jeneng pelanggan ana ing kolom B:

=B2&COUNTIF($B$2:B2,B2)

=B2&СЧЁТЕСЛИ($B$2:B2;B2)

Sawise sampeyan bisa nggunakake fungsi normal VPRkanggo nemokake pesenan sing dibutuhake. Tuladhane:

• Golek 2-th barang sing dipesen dening pelanggan Dan Brown:

  =VLOOKUP("Dan Brown2",$A$2:$C$16,3,FALSE)

  =ВПР("Dan Brown2";$A$2:$C$16;3;ЛОЖЬ)

• Golek 3-th barang sing dipesen dening pelanggan Dan Brown:

  =VLOOKUP("Dan Brown3",$A$2:$C$16,3,FALSE)

  =ВПР("Dan Brown3";$A$2:$C$16;3;ЛОЖЬ)

Nyatane, sampeyan bisa ngetik referensi sel minangka nilai goleki tinimbang teks, kaya sing ditampilake ing gambar ing ngisor iki:

Yen sampeyan mung nggoleki 2-e pengulangan, sampeyan bisa nindakake tanpa kolom tambahan kanthi nggawe rumus sing luwih rumit:

=IFERROR(VLOOKUP($F$2,INDIRECT("$B$"&(MATCH($F$2,Table4[Customer Name],0)+2)&":$C16"),2,FALSE),"")

=ЕСЛИОШИБКА(ВПР($F$2;ДВССЫЛ("$B$"&(ПОИСКПОЗ($F$2;Table4[Customer Name];0)+2)&":$C16");2;ИСТИНА);"")

Ing rumus iki:

• $F$2 - sel sing ngemot jeneng panuku (ora diganti, elinga - link kasebut mutlak);
• $B $ – kolom jeneng pelanggan;
• Table4 – Tabel Panjenengan (panggonan iki uga bisa dadi sawetara biasa);
• $C16 – sel mburi meja utawa sawetara.

Rumus iki mung nemokake nilai cocog kapindho. Yen sampeyan kudu ngekstrak repetisi sing isih ana, gunakake solusi sadurunge.

Yen sampeyan perlu dhaptar kabeh cocog - fungsi VPR iki ora helper a, awit iku mung ngasilake siji nilai ing wektu - periode. Nanging Excel duwe fungsi INDEKS (INDEX), sing bisa gampang ngatasi tugas iki. Kepiye rumus kasebut bakal katon, sampeyan bakal sinau ing conto ing ngisor iki.

Nompo kabeh repetitions saka nilai sing dikarepake

Kaya kasebut ing ndhuwur VPR ora bisa ngekstrak kabeh nilai duplikat saka kisaran sing dipindai. Kanggo nindakake iki, sampeyan butuh rumus sing rada rumit, digawe saka sawetara fungsi Excel, kayata INDEKS (INDEX), KANGGO (cilik) lan Row (LINE)

Contone, rumus ing ngisor iki nemokake kabeh pengulangan nilai saka sel F2 ing kisaran B2: B16 lan ngasilake asil saka baris sing padha ing kolom C.

{=IFERROR(INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3)),"")}

{=ЕСЛИОШИБКА(ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3));"")}

Ketik rumus array iki menyang macem-macem sel jejer, kayata sel F4: F8kaya sing dituduhake ing gambar ing ngisor iki. Jumlah sel kudu padha utawa luwih saka jumlah maksimum sing bisa diulang saka nilai sing digoleki. Aja lali klik Ctrl + Shift + Ketikkanggo ngetik rumus array kanthi bener.

Yen sampeyan kepengin ngerti cara kerjane, ayo goleki rincian rumus kasebut:

Bagian 1:

IF($F$2=B2:B16,ROW(C2:C16)-1,"")

ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"")

$F$2=B2:B16 - mbandhingake nilai ing sel F2 karo saben nilai ing kisaran B2:B16. Yen cocog ditemokake, banjur ekspresi STRING(C2:C16)-1 ngasilake nomer baris sing cocog (nilai -1 ngidini sampeyan ora kalebu baris header). Yen ora ana sing cocog, fungsi IF (IF) ngasilake string kosong.

Hasil fungsi IF (IF) bakal ana array horisontal: {1,"",3,"",5,"","","","","","",12,"","",""}

Bagian 2:

ROW()-3

СТРОКА()-3

Kene fungsi Row (LINE) tumindak minangka counter tambahan. Wiwit rumus disalin menyang sel F4:F9, kita nyuda nomer kasebut 3 saka asil fungsi kanggo entuk nilai 1 ing sel F4 (baris 4, nyuda 3) kanggo entuk 2 ing sel F5 (baris 5, nyuda 3) lan liya-liyane.

Bagian 3:

SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))

НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))

fungsi KANGGO (CIL) bali n-oh nilai paling cilik ing array data. Ing kasus kita, posisi sing (saka sing paling cilik) kanggo bali ditemtokake dening fungsi kasebut Row (LINE) (pirsani Part 2). Dadi, kanggo sel F4 fungsi Cilik({larik},1) ngasilake 1-th (paling cilik) unsur array, ie 1. Kanggo sel F5 ngasilake 2-th unsur paling cilik ing Uploaded, sing 3, Etc.

Bagian 4:

INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))

ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))

fungsi INDEKS (INDEX) mung ngasilake nilai sel tartamtu ing larik C2:C16. Kanggo sel F4 fungsi INDEKS($C$2:$C$16) bakal bali Appleskanggo F5 fungsi INDEKS($C$2:$C$16) bakal bali manisan' lan ing.

Bagian 5:

IFERROR()

ЕСЛИОШИБКА()

Pungkasan, kita sijine rumus ing fungsi kasebut IFERROR (IFERROR), amarga sampeyan ora seneng karo pesen kesalahan #AT (#N/A) yen jumlah sel sing disalin rumus kurang saka jumlah duplikat nilai ing kisaran sing dideleng.

Panelusuran XNUMXD kanthi baris lan kolom sing dikenal

Nindakake telusuran XNUMXD ing Excel kalebu nggoleki nilai kanthi nomer baris lan kolom sing dikenal. Ing tembung liyane, sampeyan ngekstrak nilai sel ing persimpangan baris lan kolom tartamtu.

Dadi, ayo pindhah menyang tabel lan nulis rumus kanthi fungsi VPR, sing bakal nemokake informasi babagan biaya lemon sing didol ing Maret.

Ana sawetara cara kanggo nindakake telusuran XNUMXD. Priksa pilihan lan pilih salah siji sing paling cocog karo sampeyan.

Fungsi VLOOKUP lan MATCH

Sampeyan bisa nggunakake sawetara fungsi VPR (VLOOKUP) lan LUWIH DIBUKA (MATCH) kanggo nemokake nilai ing persimpangan lapangan Название продукта (string) lan Wulan (kolom) saka larik ing pitakonan:

=VLOOKUP("Lemons",$A$2:$I$9,MATCH("Mar",$A$1:$I$1,0),FALSE)

=ВПР("Lemons";$A$2:$I$9;ПОИСКПОЗ("Mar";$A$1:$I$1;0);ЛОЖЬ)

Rumus ing ndhuwur minangka fungsi reguler VPR, sing nggoleki sing cocog karo nilai "Lemon" ing sel A2 nganti A9. Nanging amarga sampeyan ora ngerti kolom endi dodolan Maret, sampeyan ora bakal bisa nyetel nomer kolom kanggo argumen fungsi katelu. VPR. Nanging, fungsi kasebut digunakake LUWIH DIBUKAkanggo nemtokake kolom iki.

MATCH("Mar",$A$1:$I$1,0)

ПОИСКПОЗ("Mar";$A$1:$I$1;0)

Diterjemahake menyang basa manungsa, rumus iki tegese:

• We are looking for karakter "Mar" - argumen goleki_nilai (nilai_goleki);
• Nggoleki sel saka A1 nganti I1 - argumen lookup_array (lookup_array);
• Wangsulan sing cocog - argumen match_type (jinis_cocok).

nggunakake 0 ing argumen katelu, sampeyan ngomong fungsi LUWIH DIBUKA goleki nilai pisanan sing cocog karo nilai sing sampeyan goleki. Iki padha karo regane lupute (PALSU) kanggo argumen kaping papat VPR.

Iki carane sampeyan bisa nggawe rumus telusuran rong arah ing Excel, uga dikenal minangka telusuran rong dimensi utawa telusuran bidirectional.

Fungsi SUMPRODUCT

fungsi SUMPRODUCT (SUMPRODUCT) ngasilake jumlah produk saka array sing dipilih:

=SUMPRODUCT(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar"),$A$2:$I$9)

=СУММПРОИЗВ(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar");$A$2:$I$9)

fungsi INDEX lan MATCH

Ing artikel sabanjure aku bakal nerangake fungsi kasebut kanthi rinci, mula saiki sampeyan mung bisa nyalin rumus iki:

=INDEX($A$2:$I$9,MATCH("Lemons",$A$2:$A$9,0),MATCH("Mar",$A$1:$I$1,0))

=ИНДЕКС($A$2:$I$9;ПОИСКПОЗ("Lemons";$A$2:$A$9;0);ПОИСКПОЗ("Mar";$A$1:$I$1;0))

Dijenengi kisaran lan operator persimpangan

Yen sampeyan ora seneng karo kabeh rumus Excel sing rumit, sampeyan bisa uga seneng karo cara visual lan paweling iki:

1. Pilih tabel, bukak tab Rumus (Formula) lan klik Nggawe saka Pilihan (Gawe saka pilihan).
2. Centhang kothak baris ndhuwur (ing baris ndhuwur) lan Kolom kiwa (ing kolom sisih kiwa). Microsoft Excel bakal nemtokake jeneng kanggo kisaran saka nilai ing baris ndhuwur lan kolom kiwa spreadsheet. Saiki sampeyan bisa nggoleki nggunakake jeneng kasebut langsung tanpa nggawe rumus.
3. Ing sembarang sel kosong, nulis = jeneng_baris jeneng_kolom, contone kaya iki:

   = Lemon Mar

   … utawa kosok balene:

   = Mar Lemon

   Elinga yen jeneng baris lan kolom kudu dipisahake kanthi spasi, sing ing kasus iki dianggo kaya operator persimpangan.

Nalika sampeyan ngetik jeneng, Microsoft Excel bakal nuduhake tooltip kanthi dhaptar jeneng sing cocog, kaya nalika sampeyan ngetik rumus.

4. Pencet Ketik lan mriksa asil

Umumé, apa wae cara ing ndhuwur sing sampeyan pilih, asil panelusuran rong dimensi bakal padha:

Nggunakake sawetara VLOOKUP ing siji rumus

Mengkono yen tabel utama lan tabel goleki ora duwe kolom siji sing umum, lan iki nyegah sampeyan nggunakake fungsi sing biasa. VPR. Nanging, ana tabel liyane sing ora ngemot informasi sing kita kasengsem ing, nanging wis kolom umum karo tabel utama lan meja goleki.

Coba deleng conto ing ngisor iki. Kita duwe meja Utama kanthi kolom SKU (anyar), ngendi sampeyan pengin nambah kolom karo prices cocog saka tabel liyane. Kajaba iku, kita duwe 2 tabel goleki. Sing pisanan (Tabel Lookup 1) ngemot nomer sing dianyari SKU (anyar) lan jeneng produk, lan liya (Tabel Lookup 2) - jeneng produk lan nomer lawas SKU (lawas).

Kanggo nambah prices saka Tabel goleki kapindho menyang meja utama, sampeyan kudu nindakake tumindak dikenal minangka pindho VPR utawa nested VPR.

1. Tulis fungsi VPR, sing nemokake jeneng produk ing tabel Tabel goleki 1nggunakake SKU, minangka nilai sing dikarepake:

   =VLOOKUP(A2,New_SKU,2,FALSE)

   =ВПР(A2;New_SKU;2;ЛОЖЬ)

   kene New_SKU - jenenge range $A:$B ing meja Tabel goleki 1, 2 - iki kolom B, sing ngemot jeneng barang (ndeleng gambar ing ndhuwur)

2. Tulis rumus kanggo masang prices saka Tabel Tabel goleki 2 adhedhasar jeneng produk sing kondhang. Kanggo nindakake iki, tempel rumus sing digawe sadurunge minangka nilai goleki kanggo fungsi anyar VPR:

   =VLOOKUP(VLOOKUP(A2,New_SKU,2,FALSE),Price,3,FALSE)

   =ВПР(ВПР(A2;New_SKU;2;ЛОЖЬ);Price;3;ЛОЖЬ)

   kene price - jenenge range $A:$C ing meja Tabel goleki 2, 3 punika kolom C ngemot prices.

Tokoh ing ngisor iki nuduhake asil bali kanthi rumus sing digawe:

Substitusi dinamis data saka tabel beda nggunakake VLOOKUP lan INDIRECT

Pisanan, ayo njlentrehake apa sing dimaksudake kanthi ekspresi "Ganti dinamis data saka tabel sing beda-beda" kanggo mesthekake yen kita ngerti saben liyane kanthi bener.

Ana kahanan nalika ana sawetara sheets karo data saka format padha, lan iku perlu kanggo extract informasi sing perlu saka sheet tartamtu, gumantung ing Nilai sing dilebokake ing sel tartamtu. Aku luwih gampang nerangake iki nganggo conto.

Bayangake sampeyan duwe laporan dodolan kanggo sawetara wilayah kanthi produk sing padha lan ing format sing padha. Sampeyan pengin golek angka dodolan kanggo wilayah tartamtu:

Yen sampeyan mung duwe loro laporan kasebut, sampeyan bisa nggunakake rumus sing gampang disgracefully kanthi fungsi VPR и IF (IF) kanggo milih laporan sing dikarepake kanggo digoleki:

=VLOOKUP($D$2,IF($D3="FL",FL_Sales,CA_Sales),2,FALSE)

=ВПР($D$2;ЕСЛИ($D3="FL";FL_Sales;CA_Sales);2;ЛОЖЬ)

Where:

• $D $2 yaiku sel sing ngemot jeneng produk. Elinga yen kita nggunakake referensi absolut ing kene supaya ora ngganti nilai goleki nalika nyalin rumus menyang sel liyane.
• $D3 yaiku sel kanthi jeneng wilayah. Kita nggunakake referensi kolom absolut lan referensi baris relatif amarga kita rencana nyalin rumus menyang sel liyane ing kolom sing padha.
• FL_Sales и CA_Sales – jeneng tabel (utawa kisaran jenenge) sing ngemot laporan dodolan sing cocog. Sampeyan bisa, mesthi, nggunakake jeneng sheet biasanipun lan referensi sawetara sel, contone, 'FL Sheet'!$A$3:$B$10, nanging jenenge kisaran luwih trep.

Nanging, nalika ana akeh tabel kuwi, fungsi IF dudu solusi sing paling apik. Nanging, sampeyan bisa nggunakake fungsi kasebut LANGSUNG (TIDAK LANGSUNG) kanggo ngasilake kisaran telusuran sing dikarepake.

Kaya sing sampeyan ngerteni, fungsi kasebut LANGSUNG digunakake kanggo bali link diwenehi dening senar teks, kang persis apa kita kudu saiki. Dadi, kanthi wani ngganti rumus ing ndhuwur ekspresi kanthi fungsi kasebut IF kanggo nyambungake karo fungsi LANGSUNG. Punika kombinasi VPR и LANGSUNG dianggo apik karo:

=VLOOKUP($D$2,INDIRECT($D3&"_Sales"),2,FALSE)

=ВПР($D$2;ДВССЫЛ($D3&"_Sales");2;ЛОЖЬ)

Where:

• $D $2 - iki minangka sel kanthi jeneng produk, ora diganti amarga pranala mutlak.
• $D3 yaiku sel sing ngemot bagean pisanan saka jeneng wilayah. Ing conto kita, iki FL.
• _Sale - bagean umum saka jeneng kabeh kisaran utawa tabel sing dijenengi. Nalika digabungake karo nilai ing sel D3, iku mbentuk jeneng qualified saka sawetara sing dibutuhake. Ing ngisor iki sawetara rincian kanggo wong sing anyar ing fungsi kasebut LANGSUNG.

Cara kerja INDIRECT lan VLOOKUP

Pisanan, aku ngelingake sampeyan sintaks fungsi kasebut LANGSUNG (ora langsung):

INDIRECT(ref_text,[a1])

ДВССЫЛ(ссылка_на_текст;[a1])

Argumen pisanan bisa dadi referensi sel (gaya A1 utawa R1C1), jeneng sawetara, utawa string teks. Argumen kapindho nemtokake gaya pranala apa sing ana ing argumen pisanan:

• A1yen argumen kasebut KODE BENER (TRUE) utawa ora ditemtokake;
• R1C1, yen FAS E (PALSU).

Ing kasus kita, pranala kasebut nduweni gaya A1, supaya sampeyan bisa ninggalake argumen kapindho lan fokus ing sing pisanan.

Dadi ayo bali menyang laporan penjualan. Yen sampeyan ngelingi, banjur saben laporan minangka tabel kapisah sing ana ing lembar sing kapisah. Supaya rumus bisa mlaku kanthi bener, sampeyan kudu menehi jeneng tabel (utawa kisaran), lan kabeh jeneng kudu duwe bagean sing umum. Contone, kaya iki: CA_Sales, FL_Sales, TX_Sales lan liya-liyane. Kaya sing sampeyan ngerteni, "_Sales" ana ing kabeh jeneng.

fungsi LANGSUNG nyambungake nilai ing kolom D lan senar teks "_Sales", mangkono ngandhani VPR ing tabel apa sing kudu digoleki. Yen sel D3 ngemot nilai "FL", rumus bakal nelusuri tabel FL_Sales, yen "CA" - ing tabel CA_Sales lan ing.

Asil saka fungsi VPR и LANGSUNG bakal ing ngisor iki:

Yen data kasebut ana ing buku Excel sing beda-beda, mula sampeyan kudu nambah jeneng buku sadurunge kisaran sing dijenengi, contone:

=VLOOKUP($D$2,INDIRECT($D3&"Workbook1!_Sales"),2,FALSE)

=ВПР($D$2;ДВССЫЛ($D3&"Workbook1!_Sales");2;ЛОЖЬ)

Yen fungsi LANGSUNG nuduhake buku kerja liyane, buku kerja kasebut kudu mbukak. Yen ditutup, fungsi bakal nglaporake kesalahan. #REF! (#SSYL!).